home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (DO) / Softdisk Magazette Volume 1, No. 06 (1982-02)(Softdisk)(Side A)[b].zip / Softdisk Magazette Volume 1, No. 06 (1982-02)(Softdisk)(Side A)[b].do / WAVE.bas < prev   
BASIC Source File  |  1996-12-24  |  2KB  |  40 lines
  1. 0  POKE 216,0
  2. 5  REM  SINE WAVE TITLES
  3. 6  REM  BY DANIEL TOBIAS  1/82
  4. 10  REM  CHANGE VOLUME, NUMBER AND DATE ON LINE 160 TO CORRECT NUMBERS
  5. 15  PRINT  CHR$(4)"PR#0": TEXT 
  6. 20  HOME : PRINT : PRINT "  S O F T D I S K   M A G A Z E T T E"
  7. 30  PRINT : PRINT "            SINE WAVE COVER                         BY DANIEL TOBIAS"
  8. 40  VTAB 15: HTAB 4: PRINT "LET THIS RUN AND MENU WILL RETURN"
  9. 50  VTAB 20: HTAB 15: INVERSE : PRINT "HIT RETURN";: NORMAL : INPUT " ";R$
  10. 100  REM  INIT
  11. 110 X =  RND( -( PEEK(78) +256 * PEEK(79))): REM SEED RND 
  12. 120  FOR I = 3072 TO 3080:K =  PEEK(I) +K: NEXT I: IF K = 621  THEN  CALL 3072: GOTO 150
  13. 130  PRINT  CHR$(4)"BRUN LOMEM:": &  LOMEM: 16384
  14. 140  PRINT  CHR$(4)"BRUN CHARACTER.GEN"
  15. 150 HM$ =  CHR$(12)
  16. 160 V = 1:N = 6:DA$ = "FEB. 1982"
  17. 200  PRINT HM$
  18. 210  PRINT  CHR$(17)" SOFTDISK MAGAZETTE"
  19. 220  PRINT  CHR$(18)"      Volume "V" Number "N", "DA$
  20. 230  PRINT "++++++++++++++++++++++++++++++++++++++++"
  21. 240  VTAB 20: PRINT "++++++++++++++++++++++++++++++++++++++++"
  22. 250  PRINT  CHR$(23)"    THE WAVE OF"
  23. 260  PRINT "    THE FUTURE!"
  24. 265 R =  RND(1) *2 *3.141592654
  25. 267 R1 = 3 * RND(1):R2 = 3 * RND(1)
  26. 268 R3 =  RND(1):R4 =  RND(1)
  27. 270  FOR A = 0 TO 2 *3.141592654  STEP 3.141592654/40
  28. 280 Y1 = R3 * SIN(A *R1)
  29. 290 Y2 = R4 * SIN((A -R) *R2)
  30. 300 Y3 = Y1 +Y2
  31. 305  IF  PEEK( -16384) >128  THEN  POKE  -16368,0: GOTO 360
  32. 310  HCOLOR= 1
  33. 315 X =  INT(A *44)
  34. 320  HPLOT X,( INT(Y1 *40) +90)
  35. 330  HCOLOR= 2: HPLOT X,( INT(Y2 *40) +90)
  36. 340  HCOLOR= 7: HPLOT X,( INT(Y3 *40) +90)
  37. 350  NEXT A
  38. 360  PRINT  CHR$(4)"PR#0"
  39. 370  TEXT : HOME 
  40. 380  PRINT  CHR$(4);"PR#6"